Tutorial de TV - Transceptor IR

Nesta seção vamos controlar sua TV usando um transceptor IR e depois usar voz para controlar a TV via Alexa, Google Home ou SmartThings.

Pré-requisitos:

Transceptor IR ESP8285 ESP-01M x1.

Neste tutorial, usaremos o Transceptor IR ESP8285 ESP-01M, uma opção popular facilmente disponível online. Embora nos concentremos neste módulo específico, os conceitos podem ser aplicados a outros transmissores infravermelhos de 38KHz também.

Sinric Pro ir transceiver

Introdução rápida ao Transceptor IR ESP8285 ESP-01M

Um Módulo Transceptor WIFI Wireless Infravermelho ESP8285 é uma placa de circuito que combina duas funcionalidades:

Transceptor Infravermelho (IR): Esta parte permite que o módulo transmita e receba sinais infravermelhos. O transmissor IR está conectado ao GPIO4 e o receptor IR está conectado ao GPIO14

Módulo Wi-Fi ESP8285: Este é um chip separado na placa que permite ao módulo conectar-se a uma rede Wi-Fi. ESP8285 é um ESP8266 com Flash de 1M, que pode suportar altas temperaturas até 125 graus Celsius.

Para Carregar Firmware: Conecte o Jumper GPIO01 e GND.

Para Executar Firmware: Remova o Jumper e reconecte o programador USB

Fiação

Sinric Pro ESP8285 ESP-01M IR transceiver wiring

ESP8285	TTL
5V	5V
GND	GND
TX	RX
RX	TX

Antes de integrarmos com Sinric Pro, é importante verificar se o relé está conectado corretamente e você pode gravar sinais IR.

Passo 1: Gravando IR

Instalar IRremoteESP8266
- Clique nos itens do menu “Sketch” -> “Include Library” -> “Manage Libraries…”.
- Digite IRremoteESP8266 na caixa de pesquisa “Filter your search…” no canto superior direito.
- Clique no resultado IRremoteESP8266 da pesquisa.
- Selecione a versão que deseja instalar e clique em Install.
Conecte o Jumper GPIO0 ao GND para carregar o firmware.
Carregue o IRrecvDumpV3 Não há necessidade de alterar o sketch. Já está usando os pinos GPIO corretos.

transceiver esp8285 flash

Remova o Jumper conectando GPIO0 ao GND e reconecte o programador USB. Agora o chip ESP executará o sketch IRrecvDumpV3. Configure o BaudRate do Arduino Serial para 115200 para ver os logs.
Hora de gravar o botão power on do controle remoto da sua TV.

record tv remote esp82266

Irá produzir os códigos IR como abaixo no Monitor Serial do Arduino.

Copie o array rawData

record tv remote esp82266 arduino serial

Passo 2: Enviando IR

#include <Arduino.h>
#include <IRremoteESP8266.h>
#include <IRsend.h>

const uint16_t kIrLed = 4;

IRsend irsend(kIrLed);

uint16_t rawData[3] = {9004, 2218,  586};  // TODO: Mude isso para o botão power do seu controle remoto

void setup() {
  irsend.begin();
  Serial.begin(115200);
}

void loop() {
  Serial.println("a rawData capture from dump");
  irsend.sendRaw(rawData, 3 /* IR len */, 38 /* kHz */);  // TODO: ajuste IR len de acordo com o comprimento do rawData.
  delay(2000);
}

Carregue o sketch acima e remova o Jumper para executar o firmware.

Quando o sketch enviar o sinal, a TV deve ligar ou desligar. Agora você pode repetir o processo para gravar outros botões como volume para cima, para baixo, mudo etc..

Passo 3: Criar um novo dispositivo de TV no Sinric Pro

Faça login na sua conta Sinric Pro, vá ao menu Dispositivos à esquerda e clique no botão Adicionar Dispositivo (no canto superior esquerdo).
Digite o nome do dispositivo TV, descrição TV e selecione o tipo de dispositivo como TV.
Clique em Outros e Clique em Salvar

record tv remote esp82266 arduino serial

Sinric Pro copy device id

Copie o ID do Dispositivo, Chave do App e Segredo do App Mantenha esses valores seguros. NÃO OS COMPARTILHE EM FÓRUNS PÚBLICOS!

Passo 2: Programação

2.1 Instalar a Biblioteca Sinric Pro

Sinric Pro install SinricPro library

2.2 Código Completo

Agora podemos completar o sketch de TV SinricPro com os códigos IR.

// #define ENABLE_DEBUG
#define SINRICPRO_NOSSL
 
#ifdef ENABLE_DEBUG
  #define DEBUG_ESP_PORT Serial
  #define NODEBUG_WEBSOCKETS
  #define NDEBUG
#endif 

#include <Arduino.h>
#include <ESP8266WiFi.h>
#include <IRremoteESP8266.h>
#include <IRsend.h>

#include "SinricPro.h"
#include "SinricProTV.h"

#define WIFI_SSID         "YOUR-WIFI-SSID"    
#define WIFI_PASS         "YOUR-WIFI-PASSWORD"
#define APP_KEY           "YOUR-APP-KEY"      // Should look like "de0bxxxx-1x3x-4x3x-ax2x-5dabxxxxxxxx"
#define APP_SECRET        "YOUR-APP-SECRET"   // Should look like "5f36xxxx-x3x7-4x3x-xexe-e86724a9xxxx-4c4axxxx-3x3x-x5xe-x9x3-333d65xxxxxx"
#define TV_ID             "YOUR-DEVICE-ID"    // Should look like "5dc1564130xxxxxxxxxxxxxx"
#define BAUD_RATE         115200

const uint16_t kIrLed = 4;
IRsend irsend(kIrLed);

bool tvPowerState;

bool onPowerState(const String &deviceId, bool &state) {
  Serial.printf("TV turned %s\r\n", state?"on":"off");
  tvPowerState = state; // set powerState

  /*
    Protocol  : NEC
    Code      : 0x20DF10EF (32 Bits)
    uint16_t rawData[71] = {9032, 4476,  582, 544,  582, 546,  582, 1652,  582, 546,  582, 544,  582, 546,  582, 546,  582, 546,  582, 1654,  582, 1654,  582, 544,  582, 1654,  582, 1654,  582, 1654,  582, 1654,  582, 1654,  582, 546,  582, 544,  584, 544,  582, 1654,  582, 546,  582, 546,  582, 546,  582, 546,  582, 1654,  582, 1654,  582, 1652,  582, 546,  582, 1654,  582, 1654,  582, 1654,  582, 1654,  582, 41158,  9004, 2222,  582};  // NEC 20DF10EF
    uint32_t address = 0x4;
    uint32_t command = 0x8;
    uint64_t data = 0x20DF10EF;
  */
  
  uint16_t rawData[71] = {9032, 4476,  582, 544,  582, 546,  582, 1652,  582, 546,  582, 544,  582, 546,  582, 546,  582, 546,  582, 1654,  582, 1654,  582, 544,  582, 1654,  582, 1654,  582, 1654,  582, 1654,  582, 1654,  582, 546,  582, 544,  584, 544,  582, 1654,  582, 546,  582, 546,  582, 546,  582, 546,  582, 1654,  582, 1654,  582, 1652,  582, 546,  582, 1654,  582, 1654,  582, 1654,  582, 1654,  582, 41158,  9004, 2222,  582};  // NEC 20DF10EF
  irsend.sendRaw(rawData, 71 /* IR len */, 38 /* kHz */);
  
  return true; 
} 

// setup function for WiFi connection
void setupWiFi() {
  Serial.printf("\r\n[Wifi]: Connecting");

  #if defined(ESP8266)
    WiFi.setSleepMode(WIFI_NONE_SLEEP); 
    WiFi.setAutoReconnect(true);
  #elif defined(ESP32)
    WiFi.setSleep(false); 
    WiFi.setAutoReconnect(true);
  #endif

  WiFi.begin(WIFI_SSID, WIFI_PASS); 

  while (WiFi.status() != WL_CONNECTED) {
    Serial.printf(".");
    delay(250);
  }
  IPAddress localIP = WiFi.localIP();
  Serial.printf("connected!\r\n[WiFi]: IP-Address is %d.%d.%d.%d\r\n", localIP[0], localIP[1], localIP[2], localIP[3]);
}

// setup function for SinricPro
void setupSinricPro() {
  // add device to SinricPro
  SinricProTV& myTV = SinricPro[TV_ID];

  // set callback functions to device
  myTV.onPowerState(onPowerState);

  // For other https://github.com/sinricpro/esp8266-esp32-sdk/blob/master/examples/TV/TV.ino
  // myTV.onAdjustVolume(onAdjustVolume);
  // myTV.onChangeChannel(onChangeChannel);
  // myTV.onChangeChannelNumber(onChangeChannelNumber);
  // myTV.onMediaControl(onMediaControl);
  // myTV.onMute(onMute);  
  // myTV.onSelectInput(onSelectInput);
  // myTV.onSetVolume(onSetVolume);
  // myTV.onSkipChannels(onSkipChannels);

  // setup SinricPro
  SinricPro.onConnected([](){ Serial.printf("Connected to SinricPro\r\n"); }); 
  SinricPro.onDisconnected([](){ Serial.printf("Disconnected from SinricPro\r\n"); });
  SinricPro.begin(APP_KEY, APP_SECRET);
}

void setupIR() {
  irsend.begin();
}

// main setup function
void setup() {
  setupIR();
  
  Serial.begin(BAUD_RATE); Serial.printf("\r\n\r\n");

  setupWiFi();
  setupSinricPro();
}

void loop() {
  SinricPro.handle();
}

View this code on GitHub Gist

Agora você deve conseguir controlar a TV via App Sinric Pro, Google Home, Alexa também.

Solução de Problemas

Consulte nossa página de Solução de Problemas para possíveis soluções para seu problema.

Este documento é código aberto. Viu um erro de digitação? Por favor, crie uma issue